This script will check if a specified windows service is running, and if not, it will email a user.

This script uses the Microsoft CDO service. You will need to ensure you have permissions to relay through the SMTP server you have specified in the variables.


'check service.vbs
'/*****************************************************************/
' ABOUT:
' Checks if a service is running and emails user if it is not
'
' USAGE:
' Put this script in as a windows scheduled task
' Create and modify a copy of this file for each service you wish to monitor.
' You must change the variables below to your own values
'
' Written by Alan Byrne - 20/02/2007
'/**********************************************************/

dim objShell, objNet
dim strToEmailAddress, strFromEmailAddress, strServiceNameToCheck
dim strSMTPServer, strSMTPServerPort
dim strComputerName

Set objNet = CreateObject("WScript.NetWork")

' **** Set Variables here *****
strToEmailAddress = "alanb@domain.com"
strFromEmailAddress = "administrator@domain"
strServiceNameToCheck = "TermService"
strSMTPServer = "192.168.1.2"
strSMTPServerPort = "25"

set objShell = CreateObject("Shell.Application")

If objShell.IsServiceRunning(strServiceNameToCheck) = false then
Set objMessage = CreateObject("CDO.Message")

'Send Message
objMessage.Subject = "Service Failed: " & strServiceNameToCheck
objMessage.From = "Service Failure Notice "
objMessage.To = strToEmailAddress
objMessage.TextBody = "The service '" & strServiceNameToCheck & "' failed on " & objNet.ComputerName & vbcrlf & "Time: " & Now
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = strSMTPServer
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = strSMTPServerPort
objMessage.Configuration.Fields.Update
objMessage.Send
End if

set objShell = nothing
set objNet = Nothing

Bookmark It

Hide Sites

Related posts:

1. VB Script to check disk space and email results

Grab our Newsletter to Ensure your PC is Running Smooth!